bat命令一键式恢sqlserver数据库

引言：

现有一个数据库文件run_database.bak，需从ftp服务器上拷贝日期最接近当前日期的库文件到本地进行sqlserver数据库恢复

以下代码是完整的一键式恢库命令，将其拷贝文件中并重新命名.bat后缀，执行即可

@echo off

REM 设置FTP服务器的地址和登录凭据，如果密码中有特殊字符@  则需要转义^@
set "ftpServer=ip"
set "username=user"
set "password=password"
set "localpath=D:"
set "sqlfile=sql.fullbak"
set "runfile=run-sysdate*-full.bak"

REM 获取当前日期并进行格式化,在d：下创建一个当日文件夹  
for /F "tokens=1-3 delims=/ " %%a in ("%date%") do (
    set "year=%%a"
    set "month=%%b"
    set "day=%%c"
)

REM  校验当日文件夹是否存在
if not exist "%localpath%\%year%%month%%day%" mkdir "%localpath%\%year%%month%%day%"

REM 获取主机ip，用于后面恢库
for /f "tokens=16" %%a in ('ipconfig ^|find /i "ipv4"') do set ip=%%a

REM 使用FTP 获取到数据库列表信息
echo open %ftpServer% > ftp_commands.txt
echo %username%>> ftp_commands.txt
echo %password%>> ftp_commands.txt
echo dir %runfile%>>ftp_commands.txt
echo quit>>ftp_commands.txt
ftp -s:ftp_commands.txt > put_out.txt

REM  获取列表中所有的run库文件，并将最后一个赋值给新的变量
set lastfile=
for /f "tokens=9" %%a in ('type put_out.txt ^| findstr /i ".bak"') do (
    set "lastfile=%%a"
)
REM 再次使用FTP命令 run库下载文件到本地
echo open %ftpServer% > ftp_commands.txt
echo %username%>> ftp_commands.txt
echo %password%>> ftp_commands.txt
echo binary>> ftp_commands.txt
echo lcd %localpath%\%year%%month%%day%>> ftp_commands.txt
echo cd %lastfile%>> ftp_commands.txt
echo get %sqlfile% %sqlfile%>> ftp_commands.txt
echo get %lastfile% %lastfile%>> ftp_commands.txt
echo quit>> ftp_commands.txt
ftp -s:ftp_commands.txt > put_out.txt
REM 删除临时文件
del ftp_commands.txt
del put_out.txt

rem  一直等待本地盘符中sql库文件存在
rem 先切换到对应的盘符
:LOOP
D:
cd \
if not exist %localpath%\%year%%month%%day%\%sqlfile% (
    timeout /t 60 /nobreak >nul
	goto LOOP
)
net stop mssqlserver
net start mssqlserver
sqlcmd -S %ip% -Q "RESTORE DATABASE sql FROM DISK ='%localpath%\%year%%month%%day%\%sqlfile%' WITH REPLACE;" >> %localpath%\%year%%month%%day%\log.txt
if %errorlevel% equ 0 (
	echo sql has successed
) else (
    echo sql has failed
)

rem  一直等待本地盘符中run库文件存在
:LOOP
D:
cd \
if not exist %localpath%\%year%%month%%day%\%lastfile% (
    timeout /t 60 /nobreak >nul
	goto LOOP
)
net stop mssqlserver
net start mssqlserver
sqlcmd -S %ip% -Q "RESTORE DATABASE run FROM DISK ='%localpath%\%year%%month%%day%\%lastfile%' WITH REPLACE;" >> %localpath%\%year%%month%%day%\log.txt
if %errorlevel% equ 0 (
	echo run has successed
) else (
    echo run has failed
)
pause

上述代码中有个获取ip用于恢库的（因为使用ip可适用于所有的机器恢复 sqlserver），需要你使用的sqlserver可以使用windows身份登录

如果你的本机无法通过此登录，可以执行下面此段bat即可解决，一次修改，永久生效，

注意此sa是系统默认的用户，每个数据都有自己默认的用户密码

rem user=数据库用户sa  password=数据密码   如果密码有特殊字符  需要用 ^ 转义一下  

set "user=sa"
set "password=password"

for /f "tokens=16" %%a in ('ipconfig ^|find /i "ipv4"') do set ip=%%a
sqlcmd -S %ip% -U %user% -P %password% -Q "CREATE LOGIN [%COMPUTERNAME%\%USERNAME%] from WINDOWS; ALTER SERVER ROLE sysadmin ADD MEMBER [%COMPUTERNAME%\%USERNAME%];"
pause

当然此代码中也有不足的地方，大家可以自行完善，这里我就偷一下懒了

①ftp库文件的大小与本地磁盘大小的对比，是否可以拷贝过来

②恢库文件是否有本地足够的空间去恢库